bench/rule110.bad


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

; Parameters.
let line = 0b00000000000000000000000000000001
let max_iter = 30000

; Print current line.
fun print_line(line: int): nil {
    let i = 0
    while i < 64 {
        let val = line >> 63 - i & 0b1
        if val == 0b1 {
            print("▀ ")
        } else {
            print("  ")
        }
        set i = i + 1
    }
    println("")
}

; Get the next line.
fun next_line(line: int): int {
    let next = 0
    let j = 0
    while j < 61 {
        let val = line >> 60 - j & 0b111
        set val = cond {
            val == 1 = 1
            val == 2 = 1
            val == 3 = 1
            val == 5 = 1
            val == 6 = 1
            else = 0
        }
        set next = next | val << 61 - j
        set j = j + 1
    }
    next | 1
}

let iter = 0
while iter < max_iter {
    print_line(line)
    set line = next_line(line)
    set iter = iter + 1
}