1 files changed, 71 insertions, 0 deletions

diff --git a/bench/life.bad b/bench/life.bad
new file mode 100644
index 0000000..4dcabff
--- /dev/null
+++ b/bench/life.bad
@@ -0,0 +1,71 @@
+; This board is 8 * 8 = 64 cells.
+; let n_cells = 64
+; let board_a: int[64]
+; let board_b: int[64]
+; let stride = 8
+
+; This board is 32 * 32 = 1024 cells.
+let n_cells = 1024
+let board_a: int[1024]
+let board_b: int[1024]
+let stride = 32
+
+; Storing pointers to the front/backbuffer to avoid copying the board over.
+let front = board_a
+let back = board_b
+
+; Initialize glider
+set front[stride * 2 + 5] = 1
+set front[stride * 3 + 6] = 1
+set front[stride * 4 + 4] = 1
+set front[stride * 4 + 5] = 1
+set front[stride * 4 + 6] = 1
+
+fun print_board(board: @int): nil {
+    for let i = 0 , i < n_cells , set i += 1 {
+        if i % stride == 0 {
+            println("")
+        }
+        if board[i] == 1 print("■ ")
+        else print("· ")
+    }
+    println("")
+}
+
+fun update_board(): nil {
+    for let i = 0 , i < n_cells , set i += 1 {
+        let left     = if i > 0                 front[i - 1]          else 0
+        let right    = if i < n_cells - 1       front[i + 1]          else 0
+        let top      = if i >= stride           front[i - stride]     else 0
+        let topleft  = if i >= stride           front[i - stride - 1] else 0
+        let topright = if i >= stride           front[i - stride + 1] else 0
+        let bot      = if i <= n_cells - stride front[i + stride]     else 0
+        let botleft  = if i <= n_cells - stride front[i + stride - 1] else 0
+        let botright = if i <= n_cells - stride front[i + stride + 1] else 0
+
+        let neig = left 
+                 + right 
+                 + top 
+                 + bot 
+                 + topleft 
+                 + topright 
+                 + botleft 
+                 + botright
+
+        cond {
+            front[i] == 0 && neig == 3                = set back[i] = 1
+            front[i] == 1 && (neig == 2 || neig == 3) = set back[i] = 1
+            else                                      = set back[i] = 0 
+        }
+    }
+
+    ; Swap boards.
+    let tmp = front
+    set front = back
+    set back = tmp
+}
+
+for let n_iter = 100 , n_iter > 0 , set n_iter -= 1 {
+    print_board(front)
+    update_board()
+}