Replace `spicy` with linker scripts

3 files changed, 70 insertions, 9 deletions

diff --git a/src/entry.s b/src/entry.s
new file mode 100644
index 0000000..3ff60ba
--- /dev/null
+++ b/src/entry.s
@@ -0,0 +1,16 @@
+# Entry point for the ROM image.
+        .section .text.entry
+        .global _start
+_start:
+
+        # Set up the stack
+        la      $sp, _boot_stack
+
+        # Zero BSS.
+        la      $a0, _bss_start
+        la      $a1, _bss_end
+        subu    $a1, $a1, $a0
+        jal     bzero
+
+        # Jump to C entry point.
+        j       boot
diff --git a/src/linker.ld b/src/linker.ld
new file mode 100644
index 0000000..91bd28a
--- /dev/null
+++ b/src/linker.ld
@@ -0,0 +1,50 @@
+ENTRY(_start)
+
+STACK_SIZE = 8K;
+
+MEMORY {
+    rom (R) : ORIGIN = 0, LENGTH = 64M
+    ram (RWX) : ORIGIN = 0x80000400, LENGTH = 4M - 0x400
+}
+
+SECTIONS {
+    .header : {
+        LONG(0x80371240)
+        LONG(0x0000000f)
+        LONG(0x80000400)
+        LONG(0x0000144c)
+        . = 0x1000;
+    } >rom
+
+    .text : {
+        _text_start = .;
+        *(.text.entry)
+        *(.text .text.*)
+        *(.rodata .rodata.*)
+        *(.data .data.*)
+        _text_end = .;
+    } >ram AT>rom
+
+    .bss (NOLOAD) : ALIGN(16) {
+        _bss_start = .;
+        *(.bss .bss.*)
+        *(COMMON)
+        *(.scommon .scommon.*)
+        _bss_end = .;
+    } >ram
+
+    .stack (NOLOAD) : ALIGN(16) {
+        . += STACK_SIZE;
+        . = ALIGN(8);
+        _boot_stack = .;
+        _main_thread_stack = .;
+
+        . += STACK_SIZE;
+        . = ALIGN(8);
+        _idle_thread_stack = .;
+    } >ram
+
+    /DISCARD/ : {
+        *(*)
+    }
+}
diff --git a/src/main.c b/src/main.c
index eca114f..53612d6 100644
--- a/src/main.c
+++ b/src/main.c
@@ -2,19 +2,14 @@
 
 #include "types.h"
 
-// Get a pointer to the start (top) of a stack.
-#define STACK_START(stack) ((stack) + sizeof((stack)))
-
 //
 // Threads and stacks.
 //
 
-#define STACK_SIZE 8 * 1024
 static OSThread idle_thread;
 static OSThread main_thread;
-static u8 idle_thread_stack[STACK_SIZE]  __attribute__((aligned(8)));
-static u8 main_thread_stack[STACK_SIZE]  __attribute__((aligned(8)));
-u64 boot_stack[STACK_SIZE / sizeof(u64)] __attribute__((aligned(8)));
+extern u8 _idle_thread_stack[];
+extern u8 _main_thread_stack[];
 
 //
 // Message buffers and queues.
@@ -268,7 +263,7 @@ idle_proc(void *arg) {
     osCreatePiManager((OSPri)OS_PRIORITY_PIMGR, &pi_msg_queue, pi_msg, NUM_PI_MSGS);
 
     // Create main thread.
-    osCreateThread(&main_thread, 3, main_proc, NULL, STACK_START(main_thread_stack), 10);
+    osCreateThread(&main_thread, 3, main_proc, NULL, _main_thread_stack, 10);
     osStartThread(&main_thread);
 
     // Become the idle thread.
@@ -281,6 +276,6 @@ void
 boot(void) {
     osInitialize();
     rom_handle = osCartRomInit();
-    osCreateThread(&idle_thread, 1, idle_proc, NULL, STACK_START(idle_thread_stack), 10);
+    osCreateThread(&idle_thread, 1, idle_proc, NULL, _idle_thread_stack, 10);
     osStartThread(&idle_thread);
 }